＜このサンプルの概要＞
VB.NETのコモンダイアログ(OpenFileDialog/SaveFileDialog/ColorDialog/FontDialog)の
良く使うプロパティとメソッドをサンプルソースとして記述します。

コピー＆ペーストしてお試しください。C#.NET版もありますので比較出来ます。

OpenFileDialogのサンプル(VB.NET) OpenFileDialogのサンプル(C#.NET)
SaveFileDialogのサンプル(VB.NET) SaveFileDialogのサンプル(C#.NET)
ColorDialogのサンプル(VB.NET)    ColorDialogのサンプル(C#.NET)
FontDialogのサンプル(VB.NET)     FontDialogのサンプル(C#.NET)

' ファイル開くダイアログボックスの主なプロパティのサンプル
' あらかじめOpenFileDialogをツールボックスからフォームに追加する必要があります
Private Sub Button1_Click( _
    ByVal sender As System.Object, _
    ByVal e As System.EventArgs) Handles Button1.Click

    ' ダイアログボックスのタイトル
    OpenFileDialog1.Title = "ファイル開くダイアログボックス"

    ' 初期表示するディレクトリ
    OpenFileDialog1.InitialDirectory = "c:\temp"

    ' デフォルトの選択ファイル名
    OpenFileDialog1.FileName = "test.txt"

    ' [ファイルの種類]に表示するフィルタ
    OpenFileDialog1.Filter = _
        "テキストファイル(*.txt)|*.txt|すべてのファイル(*.*)|*.*"

    ' [ファイルの種類]の初期表示インデックス
    OpenFileDialog1.FilterIndex = 1

    ' ファイル名に拡張子を自動設定するかどうか
    OpenFileDialog1.AddExtension = True

    ' 複数のファイルを選択するかどうか
    OpenFileDialog1.Multiselect = True

    ' ファイルが存在しない時に警告メッセージを表示するかどうか
    OpenFileDialog1.CheckFileExists = True

    ' PATHが存在しない時に警告メッセージを表示するかどうか
    OpenFileDialog1.CheckPathExists = True

    ' [読み取り専用ファイルとして開く]チェックボックスを表示するかどうか
    OpenFileDialog1.ShowReadOnly = True

    ' [読み取り専用ファイルとして開く]チェックボックスのデフォルト値
    OpenFileDialog1.ReadOnlyChecked = True

    ' ダイアログを閉じる時に、カレントディレクトリを元に戻すかどうか
    OpenFileDialog1.RestoreDirectory = True

    ' [ヘルプ]ボタンを表示するかどうか
    OpenFileDialog1.ShowHelp = True

    ' ダイアログボックスを表示する
    Dim btn As DialogResult = OpenFileDialog1.ShowDialog()
    If btn = Windows.Forms.DialogResult.OK Then
        ' 選択した一つのファイルPATHを取得する
        MessageBox.Show(OpenFileDialog1.FileName & "が選択されました")
        ' 選択した複数のファイルPATHを取得する
        MessageBox.Show(OpenFileDialog1.FileNames(0) & "が選択されました")
    ElseIf btn = Windows.Forms.DialogResult.Cancel Then
        MessageBox.Show("キャンセルされました")
    End If
End Sub

' ファイル保存ダイアログボックスの主なプロパティのサンプル
' あらかじめSaveFileDialogをツールボックスからフォームに追加する必要があります
Private Sub Button2_Click( _
    ByVal sender As System.Object, _
    ByVal e As System.EventArgs) Handles Button2.Click

    ' ダイアログボックスのタイトル
    SaveFileDialog1.Title = "ファイル保存ダイアログボックス"

    ' 初期表示するディレクトリ
    SaveFileDialog1.InitialDirectory = "c:\temp"

    ' デフォルトの選択ファイル名
    SaveFileDialog1.FileName = "test.txt"

    ' [ファイルの種類]に表示するフィルタ
    SaveFileDialog1.Filter = _
        "テキストファイル(*.txt)|*.txt|すべてのファイル(*.*)|*.*"

    ' [ファイルの種類]の初期表示インデックス
    SaveFileDialog1.FilterIndex = 1

    ' ファイル名に拡張子を自動設定するかどうか
    SaveFileDialog1.AddExtension = True

    ' ファイルが存在しない時に警告メッセージを表示するかどうか
    SaveFileDialog1.CheckFileExists = False

    ' PATHが存在しない時に警告メッセージを表示するかどうか
    SaveFileDialog1.CheckPathExists = False

    ' ファイルが存在しない時にファイル作成メッセージを表示するかどうか
    SaveFileDialog1.CreatePrompt = True

    ' ファイルが存在する時に上書きメッセージを表示するかどうか
    SaveFileDialog1.OverwritePrompt = True

    ' ダイアログを閉じる時に、カレントディレクトリを元に戻すかどうか
    SaveFileDialog1.RestoreDirectory = True

    ' [ヘルプ]ボタンを表示するかどうか
    SaveFileDialog1.ShowHelp = True

    ' ダイアログボックスを表示する
    Dim btn As DialogResult = SaveFileDialog1.ShowDialog()
    If btn = Windows.Forms.DialogResult.OK Then
        ' 選択したファイルPATHを取得する
        MessageBox.Show(SaveFileDialog1.FileName & "が選択されました")
    ElseIf btn = Windows.Forms.DialogResult.Cancel Then
        MessageBox.Show("キャンセルされました")
    End If
End Sub

' 色の設定ダイアログボックスの主なプロパティのサンプル
' あらかじめColorDialogをツールボックスからフォームに追加する必要があります
Private Sub Button3_Click( _
    ByVal sender As System.Object, _
    ByVal e As System.EventArgs) Handles Button3.Click

    ' デフォルトのカスタムカラーセット
    ColorDialog1.CustomColors = New Integer() {&HFF0000, &HFF00, &HFF}

    ' カスタムカラーの作成を可能にするかどうか
    ColorDialog1.AllowFullOpen = True

    ' カスタムカラー作成画面を表示するかどうか
    ColorDialog1.FullOpen = True

    ' デフォルトカラー
    ColorDialog1.Color = Color.Red

    ' 鈍色だけに制限するかどうか
    'ColorDialog1.SolidColorOnly = True

    ' 使用可能なカラーを基本カラーセットとして表示するかどうか
    'ColorDialog1.AnyColor = True

    ' [ヘルプ]ボタンを表示するかどうか
    ColorDialog1.ShowHelp = True

    ' ダイアログボックスを表示する
    Dim btn As DialogResult = ColorDialog1.ShowDialog()
    If btn = Windows.Forms.DialogResult.OK Then
        ' 選択したカラーを取得する
        MessageBox.Show(ColorDialog1.Color.ToString() & "が選択されました")
    ElseIf btn = Windows.Forms.DialogResult.Cancel Then
        MessageBox.Show("キャンセルされました")
    End If
End Sub

' フォント設定ダイアログボックスの主なプロパティのサンプル
' あらかじめFontDialogをツールボックスからフォームに追加する必要があります
Private Sub Button4_Click( _
    ByVal sender As System.Object, _
    ByVal e As System.EventArgs) Handles Button4.Click

    ' [取り消し線],[下線],[色の選択]オプションを表示するかどうか
    FontDialog1.ShowEffects = True

    ' [色の選択]を表示するかどうか
    FontDialog1.ShowColor = True

    ' デフォルトのフォントカラー
    FontDialog1.Color = Color.Blue

    ' デフォルトのフォント
    FontDialog1.Font = New Font("ＭＳ ゴシック", 12, FontStyle.Bold)

    ' 存在しないフォントを指定した時に警告メッセージを表示するかどうか
    FontDialog1.FontMustExist = True

    ' フォンサイズ最大
    FontDialog1.MaxSize = 16

    ' フォンサイズ最小
    FontDialog1.MinSize = 11

    ' [適用]ボタンを表示するかどうか
    FontDialog1.ShowApply = True

    ' [ヘルプ]ボタンを表示するかどうか
    FontDialog1.ShowHelp = True

    ' ダイアログボックスを表示する
    Dim btn As DialogResult = FontDialog1.ShowDialog()
    If btn = Windows.Forms.DialogResult.OK Then
        ' 選択したフォントを取得する
        MessageBox.Show(FontDialog1.Font.ToString() & "が選択されました")
        MessageBox.Show(FontDialog1.Color.ToString() & "が選択されました")
    ElseIf btn = Windows.Forms.DialogResult.Cancel Then
        MessageBox.Show("キャンセルされました")
    End If
End Sub